STM32F4. Контроллер внешних прерываний

[teplofizik]

Контроллер умеет следить за линиями ввода-вывода и генерировать события по фронту сигнала и имеет 7 векторов прерываний (5 индивидуальных и 2 групповых).

За тактирование контроллера отвечает бит SYSCFGEN в регистре APB2ENR.

Регистров тут совсем немного и нас интересуют только несколько из них:
EXTI_IMR — маска разрешения прерывания. Бит 0 отвечает за нулевую линию, бит 1 за первую и т.д;
EXTI_RTSR — маска включения детектора нарастающего фронта сигнала;
EXTI_FTSR — маска включения детектора спадающего фронта сигнала;
EXTI_PR — флаги сработавшего детектора. Тут их и надо сбрасывать, Чтоб покинуть прерывание.

Номер линии совпадает с номером пина в порту. Разрешается лишь выбирать, с какого порта эта линия берётся: с порта A или с порта B, или ещё откуда. Это номера от 0 до 15. Остальные линии подключены к разным сигналам:
Линия 16: PVD.
Линия 17: RTC Alarm.
Линия 18: USB OTG FS Wakeup.
Линия 19: Ethernet Wakeup.
Линия 20: USB OTG HS Wakeup.
Линия 21: RTC Tamper и RTC TimeStamp.
Линия 22: RTC Wakeup.

Первые 5 линий имеют индивидуальные вектора EXTI0_IRQHandler, EXTI1_IRQHandler, EXTI2_IRQHandler, EXTI3_IRQHandler, EXTI4_IRQHandler. Потом линии делятся на две группы, 5-9 (EXTI9_5_IRQHandler) и 10-15 (EXTI15_10_IRQHandler). В этих векторах ещё потребуется опросить регистр EXTI_PR, чтоб понять, какая из линий сработала.

Код практически такой же, как и в предыдущем примере за исключением другой периферии.

Примерный код настройки, срабатывание по обоим фронтам по нажатию кнопки User на плате:

; Главная программа
            EXPORT __main
__main      PROC
            ; Сбросим счётчик
            MOV   R1, #0
            LDR   R7, =Counter
            STR   R1, [R7]

            ; Кнопка прицеплена на ногу PA0

            ; Разрешим прерывание от 0 линии EXTI
            MOV   R0, #EXTI0_IRQn
            BL    NVIC_EnableIRQ

            ; Загружаем базовое смещение регистра настройки тактирования
            LDR   R0, =RCC_APB2ENR
            
            ; Установить флаг разрешения тактирования SYSCFG (он же тактирует и EXTI)
            LDR   R1, [R0]
            ORR   R1, #RCC_APB2ENR_SYSCFGEN
            STR   R1, [R0]
            
            ; Загружаем базовое смещение SYSCFG
            LDR   R0, =SYSCFG_BASE
            
            ; Записываем, с каого порта берём сигнал
            ; По-человечески надо считывать регистр, обнулять нужную часть и
            ; записывать необходимое число. Но пофиг.
            LDR   R1, =0x0000         ; Порт A (0) на первые 4 пина
            STR   R1, [R0, #SYSCFG_EXTICR1_OFFSET]
            
            ; Загружаем базовое смещение EXTI
            LDR   R0, =EXTI_BASE
            
            ; Маска, разрешаем генерировать прерывание на канале 0
            LDR   R1, =EXTI_IMR_MR0
            STR   R1, [R0, #EXTI_IMR_OFFSET]
            
            ; Любой фронт
            ; В идеале тут тоже надо просто ставить бит, а не вот так
            MOV   R1, #EXTI_FTSR_TR0
            STR   R1, [R0, #EXTI_FTSR_OFFSET]
            MOV   R1, #EXTI_RTSR_TR0
            STR   R1, [R0, #EXTI_RTSR_OFFSET]
            
__mainloop  ; Вечный цикл
            ; Смотрим, что натикал счётчик
            LDR   R0, =Counter
            LDR   R1, [R0]
            
            ; Новый круг~
            B __mainloop

            ENDP

Пример обработчика прерывания:

; Внешнее прерывание
            EXPORT EXTI0_IRQHandler 
EXTI0_IRQHandler  PROC
                    ; Прерывание автоматически сохраняет состояние регистров 0-3, 12, LR, PC на стеке
                    
                    ; Увеличим счётчик на 1
                    LDR   R0, =Counter
                    LDR   R1, [R0]
                    ADD   R1, #1
                    STR   R1, [R0]
                    
                    ; Сбросим флаг прерывания (иначе никогда из него не выйдем)
                    LDR   R0, =EXTI_BASE
                    
                    ; Сброс выполняется записью бита
                    MOV   R1, #EXTI_PR_PR0
                    STR   R1, [R0, #EXTI_PR_OFFSET]
                    
                    BX LR
                    ENDP

По нажатию на кнопку переменная Counter (и регистр R1 в главном цикле) будут увеличиваться.

Интересные файлы:
main.s

Проект целиком.

Ассемблер пока что на этом заканчивается (за исключением спиноффа про GNU Assembler, но это уже разница в синтаксисе файлов, текст будет таким же), поскольку вся периферия, о которой идёт речь дальше, настраивается всё теми же командами и ничего нового я сказать не могу. Но, конечно, есть ещё ряд интересных моментов, которые я хочу посмотреть. А все примеры, представленные на Си можно будет без особых проблем переписать на ассемблер самостоятельно, если в этом возникнет необходимость.


<< Предыдущее Следующее >>

@темы: arm, программизмы, электроника, ассемблер, stm32f4discovery, stm32