STM32F4. Строки в ассемблере

[teplofizik]

Точно такой же отладочный вывод можно применять и в ассемблерном проекте. Кстати, это вполне себе повод ознакомиться с представлением строк в си и хотя бы самой простой работе с ними.
Файл retarget.c пусть и остаётся самим собой, реализация функции ITM_SendChar описана в файле cm4_core.h и пусть она там остаётся. Желающие, конечно, могут переписать на асм, она маленькая.

Строки представляются ассемблеру как массив байт:

text1 DCB "This is text", 0 ; Просто текст
text2 DCB "Text", 0x0a, "Another line: %d", 0x0a, 0 ; Текст с двумя переносами

Если будут использоваться какие-либо функции из языка Си (например, библиотечные strcmp, strcpy и т.д.), то в конце каждой должен присутствовать ноль. Он, по соглашению, и обозначает конец. За перенос строки отвечает код 0x0a (10). Коды иных спецсимволов можно узнать в таблице ASCII/ANSI.

Строки лучше всего разместить в отдельной секции с иными неизменяемыми данными. В секции кода им делать нечего. Как-нибудь так:

    AREA    |.strings|, DATA, READONLY
text1 DCB "This is text", 0 ; Просто текст
text2 DCB "Text", 0x0a, "Another line: %d", 0x0a, 0 ; Текст с двумя переносами

Использование их не представляет ничего экстраординарного:

; puts просто выводит строку, добавляя в конце символ переноса 0x0a
; puts("This is text");
; Результат: "This is text",0x0a
LDR R0, =text1
BL  puts

; printf выводит строку, заменяя комбо %что-то на значения соответствующих аргументов (согласно их порядку)
; printf("Text\nAnother line: %d\n", 1234);
; Результат: "Text", 0x0a, "Another line: 1234", 0x0a
LDR R0, =text2
LDR R1, =1234
BL  printf

Что надо передавать в printf смотрите в мануале по стандартной библиотеке языка Си.
Библиотека Microlib поддерживает это хоть и не в совсем полном объёме, но вполне достаточном для использования.

А что делать с printf и другими функциями, если аргументов больше, чем четыре?
Например, printf("%d %d %d %d %s %d", 1, 2, 3, 4, "mimimi", 5)?
Указатель на строку для форматирования записывается в регистр R0. Потом три аргумента ещё влезают в регистры R0-R3. А дальше фиг, регистров для аргументов больше нет. Регистры R4-R12 вложенная функция трогать не должна, они не для неё. Зато есть стек. Все аргументы функции, что не влезли в регистры, должны располагаться там, куда указывает SP. То есть пятый аргумент будет взят по адресу *SP, шестой по адресу *(SP + 4), седьмой - *(SP + 8) и т.д.

А для этого надо их туда поместить, ничего не сломав. Мы помним, что стек в армах растёт в сторону меньших адресов. Каждый PUSH одного регистра уменьшает SP на 4, каждый POP увеличивает на 4. Это значит, что в сторону больших адресов лежат всякие важные данные. Например, адреса возврата, сохранённые с помощью PUSH {LR}.

Если будем записывать вот так прямо по указателю SP, то всё будет плохо:

test1 PROC

      PUSH {R4, LR}
            
      MOV  R0, #0
      STR  R0, [SP]     ; Затёрли сохранённый R4
      STR  R0, [SP, #4] ; Затёрли сохранённый LR

      POP  {R4, PC}     ; Oops!
ENDP

Потому сдвинем указатель так, чтоб вся запись оказалась в безопасной и никому кроме нас не нужной зоне:

test2 PROC
	PUSH {R4, LR}
	SUB SP, SP, #8    ; Дадим себе пространства на два слова

	MOV  R0, #0
	STR  R0, [SP]     ; Всё ок!
	STR  R0, [SP, #4] ; Всё ок!

	ADD SP, SP, #8    ; Нам больше этот шлак не нужен, вернём стек к исходному состоянию, чтоб смогли вернуться
	POP  {R4, PC}     ; Всё ок!
ENDP

Так вот, для передачи дополнительных аргументов через стек, надо бы сначала указатель подвинуть на достаточное и безопасное расстояние и заполнить все значения.
Ассемблер кейла настоятельно желает, чтобы указатель стека всегда мог быть нацело поделён на 8, потому сдвигаем его на числа, кратные 8: 8, 16, 24, 32 и т.д, даже если нам

лишние байты не нужны. Размер каждого аргумента 4 байта, как размер регистра. Он не зависит от типа аргумента никак, такое вот соглашение.
Пример передачи семи аргументов в функцию printf:

	    AREA    |.strings|, DATA, READONLY
mimimi      DCB  "mimimi", 0
manyarg     DCB "%d %d %d %d %s %d", 0  ; шесть замен

	    AREA    |.text|, CODE, READONLY
main        PROC
            ; Сначала запихнём аргументы в стек, используя R0-R3 свободно.
            MOV  R0, #4
            LDR  R1, =mimimi
            MOV  R2, #5
            ; Сдвинем указатель стека на 4 слова (16 байт), чтоб не затереть ничего важного (хоть там ничего и нет)
            SUB  SP, SP, #0x10
            STR  R0, [SP, #0] ; 5 аргумент
            STR  R1, [SP, #4] ; 6 аргумент
            STR  R2, [SP, #8] ; 7 аргумент
            
            ; Теперь можно и первые 4 аргумента обычным порядком передать
            LDR  R0, =manyarg ; 1 аргумент
            MOV  R1, #1       ; 2 аргумент
            MOV  R2, #2       ; 3 аргумент
            MOV  R3, #3       ; 4 аргумент
            
            ; Аргументы подготовлены. Вызовем функцию
            BL   printf
            
            ; Вернём указатель стека на место
            ADD  SP, SP, #0x10

            ; Бесконечный цикл
__loop
            B __loop

ENDP

В общем, подобным образом можно использовать все строковые функции из стандартной библиотеки, их там много полезных.

Файлы:
main.s

Проект.

<< Предыдущее Следующее >>

@темы: arm, программизмы, ассемблер, stm32f4discovery, stm32